Форум

События в SourcePawn

root — Tue, 13 Oct 2015 22:47:05 GMT

События в SourcePawn

События - сообщения, используемые сервером для передачи сообщений и данных

Введение
События описаны в .res файлах мода в папке resource. "Стандартные" события находятся в hl2/resource/gameevents.res и hl2/resource/serverevents.res. Мод может расширить эти события с помощью расширений.
Для примера посмотрим на player_death из hl2/resource/gameevents.res:

Код

"player_death"
{
"userid" "short" // user ID убитого
"attacker" "short" // user ID убийцы
}

Counter-Strike:Source расширяет это описание в cstrike/resource/modevents.res:

Код

"player_death"
{
     "userid"   "short"      // user ID убитого
     "attacker"   "short"       // user ID убийцы
     "weapon"   "string"    // название оружие, которым убил убийца
     "headshot"   "bool"      // сигнал попадания в голову
}

Обратите внимание, что событие состоит в следующем формате:

Код

"name"
{
     "key1"   "valueType1"
     "key2"   "valueType2"
     ...
}

Посылка сообщений
Послать сообщения очень просто. Например мы хотим послать сообщение смерти используя событие player_death описанное выше. Для Counter-Strike:Source, это будет иметь вид:

Код

SendDeathMessage(attacker, victim, const String:weapon[], bool:headshot)
{
     new Handle:event = CreateEvent("player_death")
     if (event == INVALID_HANDLE)
     {
        return
     }

     SetEventInt(event, "userid", GetClientUserId(victim))
     SetEventInt(event, "attacker", GetClientUserId(attacker))
     SetEventString(event, "weapon", weapon)
     SetEventBool(event, "headshot", headshot)
     FireEvent(event)
}

Примечания:
Вы не должны вызывать CloseHandle(), FireEvent() сделает это за вас.Даже если "userid" и "attacker" являются shorts, мы отсылаем их в качестве ints. Термин "short" используется только для того, чтобы сказать движку сколько байт числа необходимо для отправки.Событие может и не создастся; это происходит если событие не существует или никто не перехватывает его. Поэтому вы должны убедиться, что вызовCreateEvent возвращает правильный Handle.Большинство событий используют userids вместо индекса.По умолчанию, FireEvent() посылает сообщения к клиенту. Это можно отключить установив dontBroadcast в true.
Перехват событий
Существует три режима перехвата событий:
Pre - Перехват события до выполнения.Post - Перехват события после выполнения.Post_NoCopy - Перехват события, но не сохраняется любая информация об этом событии (специальная оптимизация).
Перехват событий обычно делается для одной из этих целей. Для того, чтоб понять какой режим использовать, смотрите ниже список целей:
Блокировка события (предотвращение выполнения)
Всегда PreИзменение события (изменение параметров)
Всегда PreВыполнить после события (сделать что-то после того как событие произошло)
Pre если ваши действия должны произойти перед выполнением событияPost если ваши действия должны произойти после выполнением событияPostNoCopy если подходит Post и требуется только имя событияБлокировка событий
Блокировку событий сделать очень просто. Например мы хотим заблокировать событие смерти если смерть произошла от попадания в голову:

Код

public OnPluginStart()
{
     HookEvent("player_death", Event_PlayerDeath, EventHookMode_Pre)
}

public Action:Event_PlayerDeath(Handle:event, const String:name[], bool:dontBroadcast)
{
     if (GetEventBool(event, "headshot"))
     {
        return Plugin_Handled
     }
     return Plugin_Continue
}

Изменение событий
Изменить событий тоже очень просто -- события могут быть изменены в режиме перед выполнением события. Например мы хотим убрать попадание в голову со всех событий:

Код

public OnPluginStart()
{
     HookEvent("player_death", Event_PlayerDeath, EventHookMode_Pre)
}

public Action:Event_PlayerDeath(Handle:event, const String:name[], bool:dontBroadcast)
{
     SetEventBool(event, "headshot", false)
     return Plugin_Continue
}

Post Перехват событий
По умолчанию используется перехват после события и как правило наиболее используемый. Например мы хотим послать сообщение всем игрокам, которые умерли:

Код

public OnPluginStart()
{
     HookEvent("player_death", Event_PlayerDeath)
}

public Event_PlayerDeath(Handle:event, const String:name[], bool:dontBroadcast)
{
     decl String:weapon[64]
     new victimId = GetEventInt(event, "userid")
     new attackerId = GetEventInt(event, "attacker")
     new bool:headshot = GetEventBool(event, "headshot")
     GetEventString(event, "weapon", weapon, sizeof(weapon))

     decl String:name[64]
     new victim = GetClientOfUserId(victimId)
     new attacker = GetClientOfUserId(attackerId)
     GetClientName(attacker, name, sizeof(name))

     PrintToConsole(victim,
        "You were killed by \"%s\" (weapon \"%s\") (headshot \"%d\")",
        name,
        weapon,
        headshot)
}

Это будет писать игроку в консоли кто его убил, с каким оружием и было ли попадание в голову.
Обратите внимание, что возвращение значений с перехвата после события игнорируется, поэтому тег Action не нужен.

PostNoCopy Перехват событий
Наконец есть перехваты где требуется только имя события. PostNoCopy специальная оптимизация для этого. При переходе от Pre к Post, SourceMod должен дублировать событие и все значения. PostNoCopy предотвращает это.
Например мы хотим найти когда происходят определенные события.

Код

public OnPluginStart()
{
     HookEvent("game_newmap", GameEvents, EventHookMode_PostNoCopy)
     HookEvent("game_start", GameEvents, EventHookMode_PostNoCopy)
     HookEvent("game_end", GameEvents, EventHookMode_PostNoCopy)
     HookEvent("game_message", GameEvents, EventHookMode_PostNoCopy)
}

public GameEvents(Handle:event, const String:name[], bool:dontBroadcast)
{
     PrintToServer("Event has been fired (event \"%s\") (nobcast \"%d\")", name, dontBroadcast)
}

Обратите внимание, что как и обычный Post перехват, он не требует возврата значений. Однако, параметр event для PostNoCopy всегда должен быть равным INVALID_HANDLE. Таким образом параметр name должен использоваться вместо GetEventName.

Оригинал

HookEvent - Отлавливаем события

root — Sat, 31 Aug 2013 08:43:30 GMT

http://wiki.alliedmods.net/Game_Events_(Source
С помощью функции HookEvent вы можете ловить любые нужные вам события, например player_death (смерть игрока), round_start (начало раунда) и др. Список всех событий и другую информацию можете найти здесь. Без событий сделать какой-то скрипт просто не получится, так как команды могут быть выполнены только внутри функций, которые вызываются этими событиями.

Существуют и встроенные в SourceMod события, такие как OnMapStart, OnPluginStart и др (смотрите в API). Если событие должно отлавливаться постоянно, то обычноHookEvent используют в OnPluginStart, но это можно делать внутри любой функции. Если вы хотите прекратить отлавливать событие, то используйте функциюUnhookEvent (синтаксис такой же, как и в HookEvent).

Код

HookEvent("имя события", <функция/блок для обработки события>, <метод>);

Есть три метода:

EventHookMode_Pre - вызываем функцию до того, как событие произошло
EventHookMode_Post - после того, как оно произошло (по умолчанию)
EventHookMode_PostNoCopy - после того, но без переменных

Пример скрипта, в начале раунда в чате напишет продолжительность раунда в секундах:

Код

#include

public OnPluginStart()
{
                     HookEvent("round_start", round_start);
}

public round_start(Handle:event, const String:name[], bool:dontBroadcast)
{
                     PrintToChatAll("timelimit = %d", GetEventInt(event, "timelimit"));
}

В событии round_start доступны три переменные: [ timelimit, fraglimit, objective ].
Список событий и переменных можете найти здесь.

Теперь посмотрим такой вариант:

Код

#include

public OnPluginStart()
{
                     HookEvent("round_start", round_start, EventHookMode_PostNoCopy);
}

public round_start(Handle:event, const String:name[], bool:dontBroadcast)
{
                     PrintToChatAll("timelimit = %d", GetEventInt(event, "timelimit"));
}

В этом случае мы не сможем получать переменные события, так как указан метод EventHookMode_PostNoCopy. Так делать полезно только в тех случаях, когда нам просто нужно знать, что событие произошло и не нужно получать его переменные.

Метод EventHookMode_Pre:

Код

#include

public OnPluginStart()
{
                     HookEvent("round_start", round_start, EventHookMode_Pre);
}

public Action:round_start(Handle:event, const String:name[], bool:dontBroadcast)
{
                     PrintToChatAll("timelimit = %d", GetEventInt(event, "timelimit"));
                     return Plugin_Continue;
}

Блок 'public Action:round_start' выполнится до того, как начнется раунд, но здесь нужно не забывать добавлять приставку Action: и возвращать return Plugin_Continue(продолжить нормальное выполнение) или return Plugin_Handled (заблокировать). На сколько я знаю, сами события заблокировать нельзя, хотя, если вы это сделаете, то не будет никаких уведомлений о том, что оно произошло, например иконка смерти, сообщение о заходе игрока и тд.

Получать переменные событий можно с помощью данных команд:

Код

GetEventBool - получить значение bool (true или false)
GetEventInt - целое число
GetEventFloat - с точкой
GetEventString - строка

Когда плагин отключается, SM сам делает все UnhookEvent и CloseHandle.

Мини скрипты/плагины

root — Fri, 12 Apr 2013 17:31:59 GMT

Если игрок жмет F1(автопокупка), в чате пишется "guns" от него. Хорошо для DeathMatch

PHP код:

#include 
public OnPluginStart()  
{  
    RegConsoleCmd("autobuy", autobuy);  
}  

public Action:autobuy(client, args)  
{  
    FakeClientCommand(client, "say guns")  
}

Создание меню в SourcePawn

root — Tue, 26 Mar 2013 09:31:24 GMT

Создание меню в SourcePawn

SourceMod имеет обширный API для создания и отображения меню клиентам.

Стили
Объект верхнего уровня MenuStyle (IMenuStyle в C++). Есть два стиля отображения меню

Стиль Valve - так называемое "ESC" меню; 8 элементов на странице
Стиль Radio - так называемое "AMX" меню; 10 элементов на странице

Каждый MenuStyle имеет свои собственные правила и свойства. Два разных меню могут существовать на экране игрока как Valve меню и Radio меню. В то же время, SourceMod будет в состоянии управлять этими меню. Это связано с тем, что каждый стиль отслеживает свое меню отдельно.

Панели
Объект с более низким уровня интерфейсом Panels (IMenuPanel в C++). Панели позволяют сделать отображение, используя лишь только текст т.е. не используя выделительных пунктов (Select).
Панели отображаются временно. Хотя они могут быть сохранены на неопределенный срок, не рекомендуется это делать.
Стиль Valve

Максимальное количество элементов на странице 8
Заблокированные элементы не могут быть осуществлены
Raw текст не может быть осуществлен
Осуществление между текстом пространства не добавят возможности добавить в панель больше символов
Клиент должен будет нажать кнопку "ESC" или, по крайней открыть консоль для просмотра меню

Стиль Radio

Максимальное количество элементов на странице 10
Оглавление белое, элементы желтые, но если их отключить, то они будут белыми
Элемент '0' всегда белый. Это означает, что навигационные кнопки управления всегда белого цвета

Меню
Есть простые Menu (IBaseMenu в C++). Эти вспомогательные объекты, предназначенные для хранения меню на основе выбора элементов. В отличие от низкого уровня панелей, меню могут содержать множество элементов, а также могут содержать только те пункты, которые выбираются (т. е. не содержат "белого" текста).
Они делятся на две категории:
Не пронумерованные - меню содержит в себе только лишь определенное количество элементов.
Нет пунктов навигации (Вперед; Назад). Исключение: Выход.

Назад (Previous) - Используется для возвращения просмотренных элементов; Перелистываемые страницы назад

Стиль Valve: Позиция в меню: 6
Стиль Radio: Позиция в меню: 8

Далее (Next) - Используется для просматривания следующих страниц; Перелистывание страницы вперед

Стиль Valve: Позиция в меню: 7
Стиль Radio: Позиция в меню: 9

Выход (Exit) - Используется для выхода из меню

Стиль Valve: Позиция в меню: 8
Стиль Radio: Позиция в меню: 10

Цель меню - Упростить процедуру хранения и отображения информации. Таким образом, меню не позволяют добавить raw текст, так как это значительно усложняет отображение алгоритма.
Примечание. C++ API поддерживает подключение IBaseMenu процедуры отображения и добавления raw текста, это будет добавлено в сценарии API в ближайшее время.
Внутри меню отображение используется с помощью RenderMenu алгоритма. Этот алгоритм создает временную панель и наполняет ее элементы из меню. Эта панель будет отображаться на клиенте. Алгоритм пытается создать свободное перемещение между всеми меню, и во всех стилях. Таким образом, любое меню отображается с помощью IBaseMenu класса, или меню Handle будет отображаться и использоваться так же как и меню Panel API.

Обзор
Меню являются системой обратного вызова. Каждый обратный вызов представляет собой действие, которое происходит во время всего цикла действия меню. Цикл состоит из некоторых уведомлений:

Начало действия уведомлений
- Отображение уведомления клиенту
- Выбор пункта в меню
Конец действия уведомлений

Спецификация
Для C++, IBaseMenu всегда доступен. Для SourcePawn, Menu Handle и MenuAction всегда устанавливаются в MenuHandler обратного вызова. В отличие от C++, API позволяет SourcePawn выполнять определенные действия, если только меню было запрошено во время создания. Это оптимизация. Тем не менее, некоторые действия не могут быть предотвращены создания.

Start

OnMenuEnd

MenuAction_Start() в SourcePawn. Это действие не срабатывает при вызове.
- param1: Игнорирование. Всегда 0
- param2: Игнорирование. Всегда 0

Display

MenuAction_Display в SourcePawn. Это действие не срабатывает при вызове.
- param1: Индекс клиента, которому показано меню
- param2: Handle в меню

Select

MenuAction_Select в SourcePawn. Это действие срабатывает, не смотря на вызов.
- param1: Индекс клиента, который выбрал пункт
- param2: Индекс пункта, который выбрал клиент

Cancel

MenuAction_Cancel в SourcePawn. Это действие срабатывает, не смотря на вызов.
- param1: Индекс клиента, который отменил показ меню
- param2: Код причины отмены показа меню

End

MenuAction_End в SourcePawn. Это действие всегда срабатывает, то ли просьба или нет.
- param1: Причина окончания показа меню
- param2: Если param1 был MenuEnd_Cancelled, это содержит причину отмены показа меню

Панели
Для панелей, функции обратного вызова всегда меняются. Для SourcePawn, Menu Handle всегда будет INVALID_HANDLE.
Select. Выбор пункта в панели

MenuAction_Select в SourcePawn.
- param1: Индекс клиента, который выбрал пункт
- param2: Индекс пункта, который выбрал клиент

Cancel. Отмена показа панели

MenuAction_Cancel в SourcePawn.
- param1: Индекс клиента, который отменил показ панели
- param2: Код причины отмены показа панели

Пример
Разберем создание панели и меню с вопросами

Код:

ваш вопрос 1. ответ 1 2. ответ 2

Меню

PHP код: // Подключаем библиотеки #include // Старт плагина public OnPluginStart() { // Регистрируем команду, введя которую нам отобразится меню RegConsoleCmd("menu", Menu) } // Обрабатываем команду public Action:Menu(client, args) { // Создаем Handle меню // MenuHandler - Значит что, нажав на один из пунктов, произойдет дальнейшее действие // То есть, нажав к примеру на "Да", нам выведется в консоль о том, что вы выбрали именно этот пункт new Handle:menu = CreateMenu(MenuHandler) SetMenuTitle(menu, "Вы любите Counter-Strike:Source?") AddMenuItem(menu, "yes", "Да") AddMenuItem(menu, "no", "Нет") SetMenuExitButton(menu, false) DisplayMenu(menu, client, 20) return Plugin_Handled } public MenuHandler(Handle:menu, MenuAction:action, param1, param2) { /* Если пункт меню был выбран, выводим в его консоль об этом */ if (action == MenuAction_Select) { decl String:info[32] new bool:found = GetMenuItem(menu, param2, info, sizeof(info)) PrintToConsole(param1, "Вы выбрали пункт: %d (Найдено: %d Информация: %s)", param2, found, info) } /* Если клиент отменил показ меню, выводим в консоль сервера */ else if (action == MenuAction_Cancel) { PrintToServer("Клиент %d Отменил показ меню. Причина: %d", param1, param2) } /* Если показ меню закончился, закрываем Handle */ else if (action == MenuAction_End) { CloseHandle(menu) } }

Обратите внимание на несколько очень важных примечаний

Один из пунктов Select или Cancel будет направлен в действие обрабатывания меню
Пункт End всегда будет направлен в действие обрабатывания меню
Уничтожение меню следует производить только, если клиент отменил меню, или оно закончилось
В меню, по умолчанию, есть пункт выхода
Продолжительно показа меню зависит от DisplayMenu

Введение в SourcePawn программирование

root — Tue, 26 Mar 2013 08:36:53 GMT

Введение в SourcePawn программирование

Это руководство призвано дать вам самые основные представления по написанию сприптов в SourcePawn. Pawn - это "скриптовый" язык используемый для внедрения функциональности в других программах. Это означает, что это не самостоятельный язык, как C++ или Java, и его элементы будут отличаться в различных приложениях. SourcePawn - это вариация языка Pawn, используемая в SourceMod.

Это руководство не расскажет вам, как писать SourceMod плагины; оно предназначено для получения общих представлений о синтаксисе и семантике этого языка.

Особенности языка
Pawn может показаться очень похожим на другие языки программирования, например C, но Pawn от них фундаментально отличается. Не столь важно, чтобы вы сейчас же поняли его отличия, но они понадобятся, если вы уже знаете один из языков программирования:

Pawn не собирает мусор
Pawn, как язык, не имеет встроенных ресурсов памяти, и потому он не мусорит. Если функция выделит память, то вы отвечаете за её освобождение.
Pawn не объектно-ориентированный язык
Pawn является процедурным и полагается на подпрограммы. Также у него нету C подобных структур.
Pawn не функциональный
awn является процедурным и не поддерживает функции "лямбды" (Lambda), поздние присвоения и все то, что можно найти в языках высшего уровня, таких как Python и Ruby.
Pawn однопоточный
Pawn не интерпретируемый
Ну, почти. Он интерпретируется на очень низком уровне. Вы должны скомпилировать код, из которого получится бинарный файл. Эта программа будет работать на той платформе, которую использует сервер. Это ускоряет загрузку и позволяет легче находить ошибки.

Этот язык был выпущен ITB CompuPhase. Язык разработан для устройств низкого уровня и таким образом конечные программы очень маленькие по размеру и очень быстрые.

Идентификаторы/ключевые слова
Идентификаторы представляет собой набор букв, цифр и/или нижнего подчеркивания, что представляет собой нечто уникальное. Идентификаторы вводятся с учетом регистра (в отличие от PHP, где иногда это не требуется). Идентификаторы не начинаются с какого-либо специального символа, но они должны начинаться с буквы.

Есть несколько зарезервированных символов, которые имеют особое значение. Например, if, for и return специальные конструкции в языке, которые будут описаны позднее. Они не могут быть использованы в качестве названий идентификаторов.

Переменные
Существует несколько важных конструкций, которые вы должны знать, прежде чем приступить к написанию сценария. Во-первых, это переменные. Переменная - это идентификатор, который содержит данные. Например, переменная "a" может содержать числа "2", "16", "0" и так далее. Переменные создаются для хранения данных внутри программы. Переменные должны быть объявлены до их использования, с помощью ключевого слова "new". Данные можно присвоить переменной, используя знак равенства (=). Пример:

PHP код: new a, b, c, d; a = 5; b = 16; c = 0; d = 500;

В SourcePawn, переменные бывают двух типов:

Однострочные (могут содержать только произвольные числовые данные), как показано выше
Многострочные (могут содержать целый ряд текстовых символов)

Однострочные могут содержать 32 бита цифровых данных. Многострочные - последовательный список из UTF-8 символов. Однострочные не имеет своего типа, однако они могут быть маркированы(tagged). Тег позволяет вам указывать, где определенную ячейку можно использовать. Типичные теги:

(пусто), или _ - Нет тега. Обычно используют для целых чисел (Integers).
Float - используют для чисел с плавающей точкой (небольших).
bool - используют для хранения значений true (истина) или false (ложь).

Со строками все по другому, они будут рассмотрены далее.

Объявления
Примеры разных правильных объявлений переменных:

PHP код: new a = 5; new Float:b = 5.0; new bool:c = true; new bool:d = 0; // работает, поскольку 0 равно false (ложь)

Неправильные объявления переменных:

PHP код: new a = 5.0; // несоответствие тегов. 5.0 должо быть с тегом Float new Float:b = 5; // несоответствие тегов. 5 должно быть без тега.

Если переменная не определена в объявлении, то ее значение станет 0:

Присвоение

Переменным могут быть присвоены данные после создания. Пример:

PHP код: new a, Float:b, bool:c; a = 5; b = 5.0; c = true;

Комментарии
Примечания и любой текст, который пишется после "//" считается "комментарием", а не фактическим кодом. Есть два стиля комментариев:

// - двойная косая черта, всё, следующее после этой строки, игнорируется
/* */ - много-строчный комментарий, весь текст, внутри звездочек, игнорируются

Массивы
Вы можете группировать код в виде "массивов", разделенных { и }. Это фактически создает возможность работать с целым массивом как с одним оператором. Например:


Массивы с фигурными скобками используются достаточно широко в программировании. Массивы кода могут быть вложенными друг в друга. Это хорошая возможность адаптировать последовательность кода и сделать его удобочитаемым, благодаря отступам код не будет смотреться, как одна большая и длинная макаронина.

Массив объявляется с помощью квадратных скобок. Вот некоторые примеры массивов:

PHP код: new players[32]; // Набор из 32 однострочных (числовых) данных new Float:origin[3]; // Набор из 3 чисел с плавающей точкой

По умолчанию, массивам присваиваются нули. Вы можете присвоить им разные значения, однако:

PHP код: new numbers[5] = {1, 2, 3, 4, 5}; // В numbers будут храниться значения 1, 2, 3, 4 ,5 new Float:origin[3] = {1.0, 2.0, 3.0}; // В origin будут храниться значения 1.0, 2.0, 3.0

Вы можете оставить массив без размера, если вы собираетесь заранее присвоить ему данные. Например:

PHP код: new numbers[] = {1, 3, 5, 7, 9};

Компилятор будет автоматически делать вывод о том, что вы хотите получить массив размером 5.

Использование массива равносильно использованию обычной переменной. Единственное отличие состоит в том, что он должен быть индексируемым. Индексирование массива означает присутствие возможности выбрать элемент, который вы хотите использовать.

Вот пример кода с использованием индексов:

PHP код: new numbers[5], Float:origin[3]; numbers[0] = 1; numbers[1] = 2; numbers[2] = 3; numbers[3] = 4; numbers[4] = 5; origin[0] = 1.0; origin[1] = 2.0; origin[2] = 3.0;

Заметим, что индекс это текст, который находится в квадратных скобках. Индекс всегда начинается с нуля. То есть, если массив имеет N элементов, его действительный индекс от 0 до N-1. Доступ к данным с индексами работает так же, как с обычной переменной.

Использование неверного индекса вызовет ошибку. Например:

PHP код: new numbers[5]; numbers[5] = 20;

Это может выглядеть верно, но число 5 не является допустимым индексом. Наибольшим значением индекса является число 4.

Вы можете использовать любые выражения, как индекс. Например:

PHP код: new a, numbers[5]; a = 1; // сделает a = 1 numbers[a] = 4; // сделает numbers[1] = 4 numbers[numbers[a]] = 2; // сделает numbers[4] = 2

Цвет сообщений в чате

root — Fri, 01 Mar 2013 08:55:45 GMT

Как сделать сообщения разноцветными.

Код

\x01 - default (стандартный оранжевый этот)
\x03 - lightgreen/red/blue/grey (grey, если игрок в spec)
\x04 - green (зеленый)
\x05 - darkgreen (темно-зеленый)

Вот скрипт для теста:

Код

#include

public OnPluginStart()
{
       HookEvent("player_say", Say);
}

public Say(Handle:event, const String:name[], bool:dontBroadcast)
{
       new i = GetClientOfUserId(GetEventInt(event, "userid"));
       decl String:text[5];
       GetEventString(event, "text", text, sizeof(text));
       if (StrEqual(text, "1"))
       {
          PrintToChatAll("\x01...01");
          PrintToChatAll("\x03...03");
          PrintToChatAll("\x04...04");
          PrintToChatAll("\x05...05");
          PrintToChatAll("\x05...05\x04...04\x03...03\x01...01");
       }
       else if (StrEqual(text, "2"))
       {
          new Handle:h = StartMessageAll("SayText2");
          if (h != INVALID_HANDLE)
          {
             BfWriteByte(h, i);
             BfWriteByte(h, true);
             BfWriteString(h, "\x03Цветное \x04сообщение");
             EndMessage();
          }
       }
}

Результат:

Чтобы получить синий, красный, или серый цвет, используйте функцию StartMessageAll("SayText2"); - сообщение для всех, или StartMessageOne("SayText2", client); - для одного игрока. В первой строке BfWriteByte(h, i); - i это индекс игрока. Цвет сообщения зависит от команды, в которой он находится. Если он CT - сообщение будет синим, T - красным, SPEC - серым.

Таймеры в SourcePawn

root — Sun, 03 Feb 2013 05:03:54 GMT

Таймеры в SourcePawn

Введение
Таймер позволяет задать интервал, после окончания которого можно будет выполнить определенную функцию.
Все функции таймера можно посмотреть в файле timers.inc (scripting/include)

Основы использования

Одноразовые таймеры
Данный таймер будет выполняться 1 раз

PHP код: public OnPluginStart() { CreateTimer(5.0, LoadStuff); } public Action:LoadStuff(Handle:timer) { PrintToServer("Loading stuff!"); }

Данный код будет писать в консоль сервера Loading stuff!, по прошествии 5 секунд

Повторяющиеся таймеры
Повторяющиеся таймеры могут выполняться бесконечное число раз через определенный промежуток времени
Например, отобразим сообщение пять раз через интервал равный трем секундам

PHP код: DoMessage() { CreateTimer(3.0, PrintMsg, _, TIMER_REPEAT); } public Action:PrintMsg(Handle:timer) { static NumPrinted = 0 if (NumPrinted++ >= 5) { PrintToServer("Warning! This is a message."); NumPrinted = 0 return Plugin_Stop } return Plugin_Continue }

Plugin_Stop останавливает таймер, а PLUGIN_CONTINUE позволяет ему продолжать работать

Передача данных

Простые значения
Таймеры способны передавать значения в функцию обратного вызова. Это значение может быть любого типа.
Например, покажем сообщение игроку через 15 секунд после подключения на сервер

PHP код: #define MAX_PLAYERS 256 new Handle:WelcomeTimers[MAX_PLAYERS+1] public OnClientPutInServer(client) { WelcomeTimers[client] = CreateTimer(15.0, WelcomePlayer, client); } public OnClientDisconnect(client) { if (WelcomeTimers[client] != INVALID_HANDLE) { KillTimer(WelcomeTimers[client]); WelcomeTimers[client] = INVALID_HANDLE } } public Action:WelcomePlayer(Handle:timer, any:client) { PrintToConsole(client, "Welcome to the server!");

Пакеты данных

Пакеты данных Packable структур, которые могут быть использованы для проведения асинхронных данных (данные, которые должны быть сохранены и без упаковки позже). Они особенно полезны для таймеров. Следовательно, существует вспомогательная функция, называемая CreateDataTimer (), которая создает таймер с помощью дескриптора данных пакета. Handle создается и закрывается автоматически.

Приведенный выше пример был переписан так:

PHP код: #define MAX_PLAYERS 256 new Handle:WelcomeTimers[MAX_PLAYERS+1] public OnClientPutInServer(client) { new Handle:pack WelcomeTimers[client] = CreateDataTimer(15.0, WelcomePlayer, pack); WritePackCell(pack, client); WritePackString(pack, "Welcome to the server!"); } public OnClientDisconnect(client) { if (WelcomeTimers[client] != INVALID_HANDLE) { KillTimer(WelcomeTimers[client]); WelcomeTimers[client] = INVALID_HANDLE } } public Action:WelcomePlayer(Handle:timer, Handle:pack) { decl String:str[128] new client /* Set to the beginning and unpack it */ ResetPack(pack) client = ReadPackCell(pack) ReadPackString(pack, str, sizeof(str)); PrintToConsole(client, "%s", str); WelcomeTimers[client] = INVALID_HANDLE }

Примечания

Точность
Наименьший возможный интервал 0,1 секунды. Таймер имеют высокую точность (с плавающей запятой), но низкую точность, как текущее время на сервере.
Это имеет два последствия:

Если сервер стоит на паузе - таймер не будет работать.
Сервер не всегда будет повторять все в точном интервале

Смерть таймера
Все таймеры гарантированно будут убиты, когда:

Используется CloseHandle ();
Используется KillTimer ();
Используется Plugin_Stop в повторяющихся таймерах;
Используется TriggerTimer () в одноразовых таймерах;
Исполняется одноразовый таймер

При смерти таймера, если TIMER_HNDL_CLOSE установлено, то Handle будут закрыты с разрешениями, CloseHandle () используется по умолчанию. Так как таймер не может быть клонирован.

Оригинал

Файлы перевода в SourcePawn

root — Sun, 03 Feb 2013 04:47:29 GMT

Введение

Система SourceMod ML базируется на следующих терминах:

Языки: Предварительно заданные языки перевода устанавливаются в configs\languages.cfg. Если язык перевода отсутствует в этом файле, он не может быть переведен до тех пор, пока не будет добавлен в этот файл и обновлена кэш-память переводов.
Фразы/Ключи перевода: Короткие, общие ключевые фразы, используемые для определения набора переводов. Они находятся в конфигурационных файлах в папке translations. Они называются файлы перевода.
Переводы: Содержат фразы текста перевода для данного языка. Они находятся в файлах перевода.

Примечание: Переводы и Фразы чувствительны к регистру.

Формат файла

Многоязычный формат файлов перевода содержится в стандартной конфигурационной форме от Valve. Она состоит из одного главного раздела, "Phrases", который содержит любое число имен подразделов. Каждый подраздел определяется одним именем Фразы, и не могут иметь в себе подразделы. Они обладают следующими свойствами:

Ключ: "#format"
- Значение: Разделенные запятыми, пары индексов и форматов
Ключ: Двух символьный код языка.
- Значение: Языковой перевод строки.

Пример:

PHP код: "Phrases" { "Welcome" { "en" "Welcome to SourceMod" "ru" "Добро пожаловать в SourceMod" } }

В приведенном выше примере, два перевода определяется по имени фразы "Welcome" - одна для английского, и одна для русского языка. Вместе с тем, рассмотрим фразу, которая может вставлять определенные слова, как в этом примере:

PHP код: "Phrases" { "Pants" { "en" "pants" "ru" "трусы" } //НЕПРАВИЛЬНЫЙ ПРИМЕР: "Frenzzy трусы горят!" "OnFire_plural" { "en" "%s's %s are on fire!" "ru" "%s %s горят!" } }

В приведенном Выше примере, порядок слов изменился. Фраза на английском вставляет объект первым, а фраза на русском предписывает объект вторым. На русском языке фраза должна выглядеть следующим образом: Трусы Frenzzy горят!. Это создает проблему для скриптов, которые всегда просматривают формат параметров в одном порядке. Чтобы решить эту проблему, было введено свойство #format. Оно предопределяет порядок формата параметров.

Пример:

PHP код: "Phrases" { //Пример: "Трусы Frenzzy горят!" "OnFire_plural" { "#format" "{1:s},{2:s}" "en" "{1}'s {2} are on fire!" "ru" "{2} {1} горят!" } //Пример: "Привет, Frenzzy!" "Hello" { "#format" "{1:s}" "en" "Hello, {1}" "ru" "Привет, {1}" } }

Формат строки состоит из разделов которые разделяются запятыми, а каждый раздел заключен в скобках. Каждый раздел имеет индекс и спецификатор формата, которые разделяются двоеточиями. Спецификаторы формата следуют общим правилам форматирования, однако в настоящее время, они поддерживаются только в следующих видах:

d/i: Отображение десятичных/целых значений
x: Отображение шестнадцатеричных значений
f: Отображение числа с плавающей точкой
s: Отображение строки
c: Отображение символов (поддерживается UTF-8)

Заметим, что в настоящее время специальный формат типа "%T" не допускает внутри языка перевод строки.

Использование в плагине

Плагины должны вызывать функцию LoadTranslations на каждый файл с переводом, который они хотят использовать. Если это не будет сделано, то никакие переводы работать не будут, даже если другой плагин загрузил те же самые файлы. Это поможет предотвратить конфликты фраз между плагинами.

Примечание: Языковые файлы загружаться после каждой смены карты (mapchange).
Даже если плагин будет перезагружен, кэшированный перевод файлов остается до следующей карты.
Встроенный перевод работает в любых формат-классовых функциях. Вводится новый спецификатор формата '%T', который указывает формат вставки определенного перевода фразы. В отличие от всех других спецификаторов формата, он требует как минимум двух параметров:

1-ый параметр: Строка, содержащая фразу для перевода.
2-ой параметр: Одно из следующих:
- Постоянная LANG_SERVER, которая определяет язык перевода по умолчанию.
- Константа player ID, которая определяет язык перевода установленный игроком.
3-ий параметр и больше: Вывод во фразе спецификаторов формата, если это необходимо.

Пример:

PHP код: new String:name[32], String:buffer[128]; GetClientName(client, name, sizeof(name)); PrintToChat(client, "[SourceMod] %T", "Hello", client, name);

Формат параметров в отдельности:

"Hello": Фраза для перевода.
client/LANG_SERVER: Кто получит перевод фразы.
name: Имя игрока

Наконец, существует вторая форма однострочного перевода, используя '%t'. Она допускается только в функциях, которые действуют непосредственно на одного или нескольких клиентов. Она исключает второй параметр, и использует указанного клиента.

Пример:

PHP код: PrintToChat(client, "[SourceMod] %t", "Hello", name);

Как видно из этого примера, Мы не должны указывать индекс клиента больше, чем один раз. Таким образом, как правило, более удобны для использования ограниченные версии '%t' в функциях, таких как PrintToChat. Однако, в функциях, которые не "управляют игроком", таких, как Format или PrintToServer, может быть использован только '%T'.

Оригинал

Получение CommunityID (SteamID64)

root — Sun, 03 Feb 2013 04:40:17 GMT

Получение CommunityID (SteamID64)

Описание:
Данное руководство покажет и поможет вам в получении CommunityID

Использование:
Для получения ссылки клиента на профиль в STEAM нам нужен сам Steam ID. Для его получения можно воспользоваться GetClientAuthString.
Для получения ссылки нужно воспользоваться GetCommunityIDString
Пример:

Код

new String:SteamID[21] = "STEAM_0:0:6070829", String:CommunityID[18];
GetCommunityIDString(SteamID, CommunityID, sizeof(CommunityID));

Обратите внимание, что лучше всего установить размер CommunityIDs в значении 18
Ну и собственно сам stock

Код

stock bool:GetCommunityIDString(const String:SteamID[], String:CommunityID[], const CommunityIDSize)
{
     new Identifier[17] = {7, 6, 5, 6, 1, 1, 9, 7, 9, 6, 0, 2, 6, 5, 7, 2, 8};
     decl String:SteamIDParts[3][11];

     if (ExplodeString(SteamID, ":", SteamIDParts, sizeof(SteamIDParts), sizeof(SteamIDParts[])) != 3)
     {
         strcopy(CommunityID, CommunityIDSize, "");
         return false;
     }

     new SteamIDNumber[CommunityIDSize - 1];
     for (new i = 0; i < strlen(SteamIDParts[2]); i++)
     {
         SteamIDNumber[CommunityIDSize - 2 - i] = SteamIDParts[2][strlen(SteamIDParts[2]) - 1 - i] - 48;
     }

     new Current, CarryOver;
     for (new i = (sizeof(Identifier) - 1); i > -1 ; i--)
     {
         Current = Identifier [i]+ (2 * SteamIDNumber[i]) + CarryOver;
         if (i == sizeof(Identifier) - 1 && strcmp(SteamIDParts[1], "1") == 0)
         {
             Current++;
         }

         CarryOver = Current/10;
         Current %= 10;

         SteamIDNumber [i]= Current;
         CommunityID [i]= SteamIDNumber [i]+ 48;
     }
     CommunityID[CommunityIDSize - 1] = '\0';
     return true;
}

Оригинал

Установка пользовательских ViewModels на оружие

root — Sun, 03 Feb 2013 04:37:55 GMT

Установка пользовательских ViewModels на оружие

Описание:
Данное руководство покажет и поможет вам в установке пользовательских ViewModels на оружие

Код

#include
#include
#include

#pragma semicolon 1

#define EF_NODRAW 32

new CustomModel1;
new CustomModel2;

new bool:SpawnCheck[MAXPLAYERS+1];
new ClientVM[MAXPLAYERS+1][2];
new bool:IsCustom[MAXPLAYERS+1];

public OnPluginStart()
{
     HookEvent("player_death", Event_PlayerDeath);
     HookEvent("player_spawn", Event_PlayerSpawn);

     for (new client = 1; client <= MaxClients; client++)
     {
         if (IsClientInGame(client))
         {
             SDKHook(client, SDKHook_PostThinkPost, OnPostThinkPost);

             ClientVM[client][0] = GetEntPropEnt(client, Prop_Send, "m_hViewModel");

             new PVM = -1;
             while ((PVM = FindEntityByClassname(PVM, "predicted_viewmodel")) != -1)
             {
                 if (GetEntPropEnt(PVM, Prop_Send, "m_hOwner") == client)
                 {
                     if (GetEntProp(PVM, Prop_Send, "m_nViewModelIndex") == 1)
                     {
                         ClientVM[client][1] = PVM;
                         break;
                     }
                 }
             }
         }
     }
}

public OnMapStart()
{
     CustomModel1 = PrecacheModel("models/Weapons/v_smg_p90.mdl");
     CustomModel2 = PrecacheModel("models/Weapons/v_smg_tmp.mdl");
}

public OnClientPutInServer(client)
{
     SDKHook(client, SDKHook_PostThinkPost, OnPostThinkPost);
}

public OnEntityCreated(entity, const String:classname[])
{
     if (StrEqual(classname, "predicted_viewmodel", false))
     {
         SDKHook(entity, SDKHook_Spawn, OnEntitySpawned);
     }
}

public OnEntitySpawned(entity)
{
     new Owner = GetEntPropEnt(entity, Prop_Send, "m_hOwner");
     if ((Owner > 0) && (Owner <= MaxClients))
     {
         if (GetEntProp(entity, Prop_Send, "m_nViewModelIndex") == 0)
         {
             ClientVM[Owner][0] = entity;
         }
         else if (GetEntProp(entity, Prop_Send, "m_nViewModelIndex") == 1)
         {
             ClientVM[Owner][1] = entity;
         }
     }
}

public OnPostThinkPost(client)
{
     static OldWeapon[MAXPLAYERS + 1];
     static OldSequence[MAXPLAYERS + 1];
     static Float:OldCycle[MAXPLAYERS + 1];

     decl String:ClassName[30];
     new WeaponIndex;

     if (!IsPlayerAlive(client))
     {
         new spec = GetEntPropEnt(client, Prop_Send, "m_hObserverTarget");
         if (spec != -1)
         {
             WeaponIndex = GetEntPropEnt(spec, Prop_Send, "m_hActiveWeapon");
             GetEdictClassname(WeaponIndex, ClassName, sizeof(ClassName));
             if (StrEqual("weapon_ump45", ClassName, false))
             {
                 SetEntProp(ClientVM[client][1], Prop_Send, "m_nModelIndex", CustomModel1);
             }
             else if (StrEqual("weapon_mp5navy", ClassName, false))
             {
                 SetEntProp(ClientVM[client][1], Prop_Send, "m_nModelIndex", CustomModel2);
             }
         }

         return;
     }

     WeaponIndex = GetEntPropEnt(client, Prop_Send, "m_hActiveWeapon");
     new Sequence = GetEntProp(ClientVM[client][0], Prop_Send, "m_nSequence");
     new Float:Cycle = GetEntPropFloat(ClientVM[client][0], Prop_Data, "m_flCycle");

     if (WeaponIndex <= 0)
     {
         new EntEffects = GetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects");
         EntEffects |= EF_NODRAW;
         SetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects", EntEffects);

         IsCustom [client]= false;

         OldWeapon [client]= WeaponIndex;
         OldSequence [client]= Sequence;
         OldCycle [client]= Cycle;

         return;
     }

     if (WeaponIndex != OldWeapon[client])
     {
         GetEdictClassname(WeaponIndex, ClassName, sizeof(ClassName));
         if (StrEqual("weapon_ump45", ClassName, false))
         {
             new EntEffects = GetEntProp(ClientVM[client][0], Prop_Send, "m_fEffects");
             EntEffects |= EF_NODRAW;
             SetEntProp(ClientVM[client][0], Prop_Send, "m_fEffects", EntEffects);
             EntEffects = GetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects");
             EntEffects &= ~EF_NODRAW;
             SetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects", EntEffects);

             SetEntProp(ClientVM[client][1], Prop_Send, "m_nModelIndex", CustomModel1);
             SetEntPropEnt(ClientVM[client][1], Prop_Send, "m_hWeapon", GetEntPropEnt(ClientVM[client][0], Prop_Send, "m_hWeapon"));

             SetEntProp(ClientVM[client][1], Prop_Send, "m_nSequence", GetEntProp(ClientVM[client][0], Prop_Send, "m_nSequence"));
             SetEntPropFloat(ClientVM[client][1], Prop_Send, "m_flPlaybackRate", GetEntPropFloat(ClientVM[client][0], Prop_Send, "m_flPlaybackRate"));

             IsCustom [client]= true;
         }
         else if (StrEqual("weapon_mp5navy", ClassName, false))
         {
             new EntEffects = GetEntProp(ClientVM[client][0], Prop_Send, "m_fEffects");
             EntEffects |= EF_NODRAW;
             SetEntProp(ClientVM[client][0], Prop_Send, "m_fEffects", EntEffects);

             EntEffects = GetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects");
             EntEffects &= ~EF_NODRAW;
             SetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects", EntEffects);

             SetEntProp(ClientVM[client][1], Prop_Send, "m_nModelIndex", CustomModel2);
             SetEntPropEnt(ClientVM[client][1], Prop_Send, "m_hWeapon", GetEntPropEnt(ClientVM[client][0], Prop_Send, "m_hWeapon"));

             SetEntProp(ClientVM[client][1], Prop_Send, "m_nSequence", GetEntProp(ClientVM[client][0], Prop_Send, "m_nSequence"));
             SetEntPropFloat(ClientVM[client][1], Prop_Send, "m_flPlaybackRate", GetEntPropFloat(ClientVM[client][0], Prop_Send, "m_flPlaybackRate"));

             IsCustom [client]= true;
         }
         else
         {
             new EntEffects = GetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects");
             EntEffects |= EF_NODRAW;
             SetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects", EntEffects);

             IsCustom [client]= false;
         }
     }
     else
     {
         if (IsCustom[client])
         {
             SetEntProp(ClientVM[client][1], Prop_Send, "m_nSequence", GetEntProp(ClientVM[client][0], Prop_Send, "m_nSequence"));
             SetEntPropFloat(ClientVM[client][1], Prop_Send, "m_flPlaybackRate", GetEntPropFloat(ClientVM[client][0], Prop_Send, "m_flPlaybackRate"));

             if ((Cycle < OldCycle[client]) && (Sequence == OldSequence[client]))
             {
                 SetEntProp(ClientVM[client][1], Prop_Send, "m_nSequence", 0);
             }
         }
     }
     if (SpawnCheck[client])
     {
         SpawnCheck [client]= false;
         if (IsCustom[client])
         {
             new EntEffects = GetEntProp(ClientVM[client][0], Prop_Send, "m_fEffects");
             EntEffects |= EF_NODRAW;
             SetEntProp(ClientVM[client][0], Prop_Send, "m_fEffects", EntEffects);
         }
     }

     OldWeapon [client]= WeaponIndex;
     OldSequence [client]= Sequence;
     OldCycle [client]= Cycle;
}

public Event_PlayerDeath(Handle:event, const String:name[], bool:dontBroadcast)
{
     new UserId = GetEventInt(event, "userid");
     new client = GetClientOfUserId(UserId);

     new EntEffects = GetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects");
     EntEffects |= EF_NODRAW;
     SetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects", EntEffects);
}

public Event_PlayerSpawn(Handle:event, const String:name[], bool:dontBroadcast)
{
     new UserId = GetEventInt(event, "userid");
     new client = GetClientOfUserId(UserId);

     SpawnCheck [client]= true;
}

Оригинал