Функции

Следующим важным понятием являются функции. Функции идентификаторов или имен, которые выполняют действия. Это означает, что когда вы их активируете, они выполняют конкретную последовательность кода. Есть несколько типов функций, но все функции активируется одинаковым образом. "Вызов функции" является термином ссылающимся на функцию действия. Функция числовых переменных строятся так:

Примеры: 

PHP код:

show(56);   // Активирует функцию "show" и присваивает ей число 56
show();     // Активирует функцию "show" без каких-либо данных, пустую
show(a);    // Активирует функцию "show" и присваивает ей переменную с данными переменной a

Каждый фрагмент данных передаваемый вызываемой функции, называется параметр. Функция может иметь любое количество параметров (но есть "допустимый" предел в SourceMod: 32).

Существуют два типа вызова функции: 

• Прямой вызов - вы специально вызываете функцию в своем коде.
• Обратный вызов - применение вызова функции в вашем коде, как если бы это было событием триггера (совокупность условий, инициирующих выполнение действия).

Существуют пять видов функций: 

• native - прямая, внутренняя функция, предусмотренная в приложении.
• public - функция обратного вызова, что делает её видимой для приложения и других сценариев.
• normal - нормальная функция, которую вы можете только вызвать.
• stock - нормальная функция, которая если не используется, то не компилируется.
• forward - функция представляет собой глобальное событие, если вы его вызвали, то она будет исполняться.

Весь код в Pawn должен существовать в функциях. Это основное отличие от языков, таких как PHP, Perl и Python, которые позволяют вам писать глобальный код. Это происходит потому, что Pawn вызывается на основе другого языка: он реагирует на действия от родительского приложения и функции должны быть написаны для обработки этих действий.

В отличие от переменных функции не нужно объявлять, прежде чем использовать их. Функции имеют две части: модель и тело. Модель содержит имя вашей функции и параметры, которые она будет принимать. Тело представляет собой простой блок кода.

Пример функции: 

PHP код:

AddTwoNumbers(first, second)
{
  new sum = first + second;
 
  return sum;
}

Это простая функция. Модель этой строки: 

PHP код:

AddTwoNumbers(first, second)

Разберем по отдельности:
AddTwoNumbers - название функции.
first - название первого параметра, который представляет собой простой элемент. 
second - название второго параметра, который представляет собой простой элемент. 

В теле создается новая переменная sum и присваивается ей значение этих двух параметров, добавленных совместно (другие выражения будут позже). Важно заметить, что оператор return обозначает конец функции и возврат с полученными значениями из этой функции. Все функции возвращают значения после завершения. Это означает, например: 

PHP код:

new sum = AddTwoNumbers(4, 5);

Приведенный выше код будет присваивать число 9 к sum. Функция получает два значения и передает новое значение sum в качестве возвращаемого значения. Если функция не имеет возвращаемого значения или не имеет значений для возврата, то возвращается 0 по умолчанию. 

Функция может принимать любые типы значений. Она может вернуть любую однострочную переменную, но не массивы или строки. Пример: 

PHP код:

Float:AddTwoFloats(Float:a, Float:b)
{
   new Float:sum = a + b;
 
   return sum;
}

Заметим, что если в приведенной выше функции вам вернулось не Float значение, то вы получите не соответствие значений. 

Можно, конечно, передавать переменные в функции: 

PHP код:

new numbers[3] = {1, 2, 0};
 
numbers[2] = AddTwoNumbers(numbers[0], numbers[1]);

Заметим, что однострочные переменные передаются по значению. То есть их значение не может быть изменено функцией. Например: 

PHP код:

new a = 5;
 
ChangeValue(a);
 
ChangeValue(b)
{
   b = 5;
}

Этот код не будет менять значение a. Это происходит потому, что копия этого значения передается в b вместо a самостоятельно. 

public
Публичные функции используются для осуществления обратных вызовов. Вы не должны создавать какую-либо публичную функцию, если это вынудит выполнение обратного вызова. Например, вот два обратных вызова из sourcemod.inc: 

PHP код:

forward OnPluginStart();
forward OnClientDisconnected(client);

Чтобы выполнить и получить эти два события, вы должны написать такие функции как: 

PHP код:

public OnPluginStart()
{
   /* Здесь код */
}
 
public OnClientDisconnected(client)
{
   /* Здесь код */
}

Ключевое слово public делает функцию публичной, а также позволяет родительскому приложению непосредственно вызывать функцию.

native
Native имеют встроенные функции, предоставляемые приложением. Вы можете вызвать их, как если бы они были normal функциями. Например, SourceMod имеет следующие функции: 

PHP код:

native FloatRound(Float:num);

Её можно вызвать таким образом: 

PHP код:

new num = FloatRound(5.2);     // Результат в num = 5

Параметры массива
Вы можете передавать массивы или строки в качестве параметров. Важно отметить, что они идут как ссылка, то есть копия данных не делается, а отдается непосредственно ссылка на данные. Существует простой способ объяснить это более конкретно. 

PHP код:

new example[] = {1, 2, 3, 4, 5};
 
ChangeArray(example, 2, 29);
 
ChangeArray(array[], index, value)
{
   array[index] = value;
}

Эта функция устанавливает заданный индекс в массиве с учетом значения. Когда она запускается на примере нашего массива, она меняет индекс 2 для значения 3 на 29. То есть: 

PHP код:

example[2] = 29;

Это возможно лишь потому, что массив может быть непосредственно изменён. Чтобы предотвратить массив от изменения, можно пометить его как постоянную const. Это позволит понизить риск на ошибку в коде от её изменения. Например: 

PHP код:

CantChangeArray(const array[], index, value)
{
   array[index] = value;    // Не компилируется
}

Используя const в параметрах массивов, вы будете точно знать, что он не будет изменен.

Выражения
Выражения являются точно такими же, какими они существуют в математике. Это группы операторов/символов, которые приходятся на один фрагмент данных. Они часто заключены в скобках (внутри скобок). Они содержат строгий "порядок операций". Они могут содержать переменные, функции, цифры и выражения сами могут быть вложенные внутрь других выражений, и даже приняты в качестве параметров. 

Приведем пример простейшего выражения: 

PHP код:

0;   // Возвращает число 0
(0); // Также возвращает число 0

Хотя выражения могут возвращать значения, они также могут ответить какое значение содержит ответ ноль или не ноль. В этом смысле, ноль является ложью (false), а не нулевое значение истиной (true). Например, -1 истина в Pawn, поскольку она не является нулем. Не думайте, что отрицательные числа являются ложными. 

Порядок операций выражения аналогичен языку C. Вот несколько примеров выражений: 

PHP код:

5 + 6;                   // Вычисляет как 11
5 * 6 + 3;               // Вычисляет как 33
5 * (6 + 3);             // Вычисляет как 45
5.0 + 2.3;               // Вычисляет как 7.3
(5 * 6) % 7;             // Модульный оператор, вычисляет как 2
(5 + 3) / 2 * 4 - 9;     // Вычисляет как 7

Как уже отмечалось, выражения могут содержать переменные, или даже функции: 

PHP код:

new a = 5 * 6;
new b = a * 3;      // Вычисляет как 90
new c = AddTwoNumbers(a, b) + (a * b);

Операторы
Есть несколько полезных дополнительных операторов в Pawn. Например: 

PHP код:

new a = 5;
 
a = a + 5;

Может быть переписан, как: 

PHP код:

new a = 5;
a += 5;

Это верно в отношении следующих операторов в Pawn:

Кроме того, существуют операторы увеличение/понижения: 

PHP код:

a = a + 1;
a = a - 1;

Может быть упрощено, как: 

PHP код:

a++;
a--;

Дополнительно отметим, что ++ или -- может быть представлен до переменной (до-инкремент, до-декремент) или после переменной (пост-инкремент, пост-декремент). Разница заключается в том, как остальная часть выражения видит результат. 
До: переменная увеличивается до определения и остальная часть выражения видит новое значение. 
Пост: переменная увеличивается после определения и остальная часть выражения видит старое значение.

Например: 

PHP код:

new a = 5;
new b = a++;   // b = 5, a = 6
new c = ++a;   // a = 7, c = 7

Операторы сравнения
Существуют шесть операторов для сравнения двух числовых значений, а результат является либо истиной (не ноль), либо ложью (ноль): 

• a == b - действительно, если a и b имеют одинаковые значения.
• a != b - действительно, если b имеет другое значение.
• a > b - действительно, если a больше b
• a >= b - действительно, если a больше или равно b
• a < b - действительно, если a меньше b
• a <= b - действительно, если a меньше или равно b

Например: 

PHP код:

(1 != 3);         // Определяется как истина, поскольку 1 не равно 3
(3 + 3 == 6);     // Определяется как истина, поскольку 3+3 равно 6
(5 - 2 >= 4);     // Определяется как ложь, поскольку 3 меньше 4

Заметим, что эти операторы не работают с массивами и строками. То есть, вы не можете сравнить их с помощью ==.

Действительные операторы
Действительные операторы могут быть скомбинированы тремя булевыми (boolean) операторами: 

• a && b - истина, если a и b истинные. Ложь, если a и (или) b ложные.
• a || b - истина, если a или b (или обе переменные) истинные. Ложь, если обе переменные a и b ложные.
• !a - Истина, если a ложь. Ложь, если a истина.

Например: 

PHP код:

(1 || 0);         // Определяется как истина, так как выражение 1 истинное
(1 && 0);         // Определяется как ложь, так как выражение 0 ложное
(!1 || 0);        // Определяется как ложь, так как выражение !1 ложное

Левое/правое значения
Два важных понятия левого и правого значений или левостороннее и правостороннее значения. Левостороннее значение имеет то, что появляется на левой стороне выражения, а правостороннее значение - на правой стороне выражения. 

Например: 

PHP код:

new a = 5;

В этом примере a является левосторонним значением и 5 является правосторонним значением. 

Правила: 

• Выражения никогда не будут левосторонними значениями.
• Переменные являются двумя: левосторонними и правосторонними значениями.

Условия
Условия позволяют вам запускать код, если определенное условие выполнено.

Если соответствует (if/else if)
Если соответствует одно или более условий. Например: 

PHP код:

if (a == 5)
{
   /* Код будет запущен, если условие будет истинным */
}

Они могут быть расширены для более сложных случаев: 

PHP код:

if (a == 5)
{
   /* Код */
}
else if (a == 6)
{
   /* Код */
}
else if (a == 7)
{
   /* Код */
}

Вы также можете обрабатывать случаи, даже если выражение не верно. Например: 

PHP код:

if (a == 5)
{
   /* Код */
}
else
{
   /* Код, который будет запущен если нет истинного выражения */
}

Оператор выбора (switch)
Оператор выбора будет ограничен условием. Он необходим для выражения, выполняющего код для целого ряда возможных значений. Например: 

PHP код:

switch (a)
{
   case 5:
   {
      /* Код, который будет выполняться, если a равно 5 */
   }
   case 6:
   {
      /* Код, который будет выполняться, если a равно 6 */
   }
   case 7:
   {
      /* Код, который будет выполняться, если a равно 7 */
   }
   case 8, 9, 10:
   {
      /* Код, который будет выполняться, если a равно или 5, или 9, или 10 */
   }
   default:
   {
      /* Код, который будет выполняться, если ни одно условие не соответствует */
   }
}

Циклы
Циклы позволяют вам без труда повторять выполнение кода, пока условие истинно.

For циклы
For циклы - это циклы, которые состоят из четырех частей: 

• Оператор инициализации - запускается один раз перед первым циклом.
• Оператор условия - проверяет условие и запускает следующий цикл, в том числе первый. Цикл прекращается, когда это выражение становится ложным.
• Оператор итерации - запускается после каждого цикла.
• Тело цикла - запускается каждый раз, пока оператор условия вычисляется как истинный.

PHP код:

for ( /* инициализация */ ; /* условие */ ; /* итерация */ )
{
   /* тело */
}

Простым примером является функция сложения массива: 

PHP код:

new array[10] = {1, 2, 3, 4, 5, 6, 7, 8, 9, 10};
new sum = SumArray(array, 10);
 
SumArray(const array[], count)
{
   new total;
 
   for (new i = 0; i < count; i++)
   {
      total += array[i];
   }
 
   return total;
}

Разберем подробнее:
new i = 0 - создает новую переменную для цикла i и устанавливает её в 0. 
i < count - только запускает цикл, если i меньше, чем count. Это гарантирует, что чтение цикла прекращается в определенный момент. В этом случае, мы не хотим читать недействительные индексы в массиве. 
i++ - увеличивает i на единицу после каждого цикла. Это гарантирует, что цикл не будет запущен вечно. В конце концов i станет слишком большим и цикл завершится. 

Таким образом, функция SumArray будет циклом каждого действительного индекса массива, каждый раз добавляя это значение в sum.

While циклы
While циклы являются менее распространенными, чем for циклы, но на самом деле это более простые циклы. Они имеют только две части: 

• Оператор условия - проверяется перед началом каждого цикла. Цикл прекращается, когда условие становится ложным.
• Тело цикла - запускается каждый раз пока цикл выполняется.

PHP код:

while ( /* условие */ )
{
   /* тело */
}

До тех пор, пока условие выражения остается истинным, цикл будет выполняться. Каждый for цикл может быть переписан, как while цикл: 

PHP код:

/* инициализация */
while ( /* условие */ )
{
   /* тело */
   /* итерация */
}

Пример предыдущего for цикла, переписанного, как while цикл: 

PHP код:

SumArray(const array[], count)
{
   new total, i;
 
   while (i < count)
   {
      total += array[i];
      i++;
   }
 
   return total;
}

Существуют также do...while циклы, которые используются еще реже. Они работают как и while циклы, но проверяют условие после каждого цикла, а не перед ним. Это означает, что цикл всегда будет запущен, по крайней мере один раз. Например: 

PHP код:

do
{
   /* тело */
}
while ( /* условие */ );